【簡単エクセルマクロ・VBA】ファイル名を変更する｜Name関数｜ファイル操作 #009

Sub Sample()


' 変数宣言
Dim original_filename As String
Dim new_filename As String


' 変更前及び変更後のファイル名（パス）を変数に代入する
original_filename = ThisWorkbook.Path & "\001_変更前\変更前のファイル名1.xlsx"
new_filename = ThisWorkbook.Path & "\002_変更後\変更後のファイル名1.xlsx"


' ファイル名を変更する
Name original_filename As new_filename


End Sub

' 変数宣言
Dim original_filename As String
Dim new_filename As String

' 変更前及び変更後のファイル名（パス）を変数に代入する
original_filename = ThisWorkbook.Path & "\001_変更前\変更前のファイル名1.xlsx"
new_filename = ThisWorkbook.Path & "\002_変更後\変更後のファイル名1.xlsx"

' ファイル名を変更する
Name original_filename As new_filename

Name 変更前のファイル名（ファイルパス） As 変更後のファイル名（ファイルパス）

Sub Sample2()

    ' 参照設定が必要なライブラリ
    ' Microsoft Scripting Runtime 

    
    ' 変数宣言
    Dim twb As Workbook
    Dim twb_ws1 As Worksheet
    
    Dim fso As FileSystemObject
    Dim source_directory As String
    Dim source_file As Object
    
    Dim row_idx As Long
    
    
    ' ワークブックとワークシートを変数に代入
    Set twb = ThisWorkbook
    Set twb_ws1 = twb.Worksheets(1)
    
    
    ' オブジェクトを変数に代入
    Set fso = New FileSystemObject
    
    
    ' ソースディレクトリを変数に代入
    source_directory = ThisWorkbook.Path & "\001_変更前"
    
    
    ' 書き込み用の行番号変数の初期値を設定
    row_idx = 6
    
    
    ' ソースディレクトリ内の全ファイルを順番に処理
    For Each source_file In fso.GetFolder(source_directory).Files
    
        ' シートにファイル名を出力
        twb_ws1.Cells(row_idx, 2) = source_file.Name
        
        
        ' 行番号変数に + 1
        row_idx = row_idx + 1
    
    Next source_file


End Sub

Sub Sample3()

    ' 参照設定が必要なライブラリ:
    ' Microsoft Scripting Runtime

    ' 変数宣言
    Dim twb As Workbook                    ' 現在のワークブックを格納する変数
    Dim twb_ws1 As Worksheet               ' 現在のワークブックの最初のワークシートを格納する変数
    Dim fso As FileSystemObject            ' ファイルシステム操作を行うオブジェクトを格納する変数
    Dim source_directory As String         ' 変更前のファイルがあるディレクトリパスを格納する変数
    Dim destination_directory As String    ' 変更後のファイルを保存するディレクトリパスを格納する変数
    Dim last_row As Long                   ' 処理対象の最終行を格納する変数
    Dim row_idx As Long                    ' ループ処理で使用する行番号を格納する変数
    
    
    ' ワークブックとワークシートを変数に代入
    Set twb = ThisWorkbook
    Set twb_ws1 = twb.Worksheets(1)
    
    
    ' オブジェクトを変数に代入
    Set fso = New FileSystemObject
    
    
    ' ソースディレクトリ、ディスティネーションディレクトリを変数に代入
    source_directory = ThisWorkbook.Path & "\001_変更前\"
    destination_directory = ThisWorkbook.Path & "\002_変更後\"
    
    
    ' 最終行の取得
    last_row = twb_ws1.Cells(twb_ws1.Rows.Count, 2).End(xlUp).Row
    
    
    ' 行をループして処理
    For row_idx = 6 To last_row
        
        ' ファイル名に"除外"を含むファイルを除外する
        If InStr(twb_ws1.Cells(row_idx, 3), "除外") = 0 Then
            
            ' 名称を変更したファイルを "002_変更後" に出力
            Name source_directory & twb_ws1.Cells(row_idx, 2) _
            As destination_directory & twb_ws1.Cells(row_idx, 3)
            
        End If
    
    Next row_idx

End Sub