【簡単エクセル/Excel VBA マクロ】異なるファイル（複数ファイル）間のデータマッチング（照合・突合）第2版｜アプリ事例 #010

your_folder/
　　├── BaseFile.xlsx
　　├── CheckFile.xlsx
　　└── データをマッチングする.xlsm

Option Explicit


Sub MatchFileData()

    
    ' 変数宣言
    Dim base_fp         As String       ' Base File のパス
    Dim base_wb         As Workbook     ' Base Workbook
    Dim base_ws         As Worksheet    ' Base Worksheet
    Dim base_last_row   As Long         ' Base Worksheet の終端行
    Dim base_row        As Long         ' Base Worksheet の行ループ用変数
    Dim base_value      As Variant      ' Base Worksheet のイテレーター値
    
    Dim check_fp        As String       ' Check File のパス
    Dim check_wb        As Workbook     ' Check Workbook
    Dim check_ws        As Worksheet    ' Check Worksheet
    Dim check_last_row  As Long         ' Check Worksheet の終端行
    Dim check_row       As Long         ' Check Worksheet の行ループ用変数
    Dim check_value     As Variant      ' Check Worksheet のイテレーター値
       
    ' 定数設定 ↓ここを修正して使用してください↓
    Const BASE_FILE_NAME    As String = "BaseFile.xlsx"
    Const BASE_TARGET_COL   As Long = 1
    Const CHECK_FILE_NAME   As String = "CheckFile.xlsx"
    Const CHECK_TARGET_COL  As Long = 1


    ' Base File （基準ファイル）を開く
    base_fp = ThisWorkbook.Path & "\" & BASE_FILE_NAME
    Set base_wb = Workbooks.Open(base_fp)
    Set base_ws = base_wb.Worksheets(1)
    base_last_row = base_ws.Cells( _
        base_ws.Rows.Count, BASE_TARGET_COL _
    ).End(xlUp).Row
    
    ' Check File （チェック対象ファイル）を開く
    check_fp = ThisWorkbook.Path & "\" & CHECK_FILE_NAME
    Set check_wb = Workbooks.Open(check_fp)
    Set check_ws = check_wb.Worksheets(1)
    check_last_row = check_ws.Cells( _
        check_ws.Rows.Count, CHECK_TARGET_COL _
    ).End(xlUp).Row
    
        
    ' Base File の行をループ
    For base_row = 1 To base_last_row
        
        ' Base File の値を変数に代入
        base_value = base_ws.Cells(base_row, BASE_TARGET_COL)
            
        ' Check File の行をループ
        For check_row = 1 To check_last_row
            
            ' Check File の値を変数に代入
            check_value = check_ws.Cells(check_row, CHECK_TARGET_COL)
            
            ' Base File の値と Check File の値が一致したら
            If base_value = check_value Then
                
                ' ここに行いたい処理を書く
                Debug.Print check_row, check_value
            
            End If
        
        Next check_row
    
    Next base_row

    ' Cleanup
    base_wb.Close SaveChanges:=False
    check_wb.Close SaveChanges:=False


End Sub