【Excel VBA 再利用コード集】結合セルの行高を自動調整

Option Explicit


Sub SetRowHeight_ByLineBreaks()

    ' Description
    '   選択範囲内のセルを走査し、
    '   セル内の改行数に応じて行高を自動調整する。
    '   ※ActiveWindow.Selection を使用するため、別ブックでも動作する。
    
    ' 変数宣言
    Dim target_rng         As Range   ' 行高調整対象の選択範囲
    Dim cell_rng           As Range   ' セル走査用

    Dim base_row_height    As Double  ' 標準行高
    Dim line_row_height    As Double  ' 改行1行分の行高

    Dim cell_text          As String  ' セル内容
    Dim line_count         As Long    ' セル内行数
    Dim max_line_count     As Long    ' 最大行数
    Dim target_row_height  As Double  ' 設定行高
    

    ' ActiveWindow の Selection を行高調整対象として取得（別ブック対応）
    If ActiveWindow Is Nothing Then Exit Sub
    If TypeName(ActiveWindow.Selection) <> "Range" Then Exit Sub
    Set target_rng = ActiveWindow.Selection

    ' 行高の基準値を取得
    base_row_height = target_rng.Worksheet.StandardHeight
    line_row_height = base_row_height

    ' 最大行数を初期化
    max_line_count = 1

    ' 複数セル選択も想定し、選択範囲内セルを走査して最大行数を取得
    For Each cell_rng In target_rng.Cells

        ' 結合セルは左上セルのみ評価
        If cell_rng.MergeCells Then
            If cell_rng.Address <> cell_rng.MergeArea.Cells(1, 1).Address Then
                GoTo ContinueCell
            End If
        End If

        ' セル内容を取得（表示形式の影響を避けるため value"2" を使用）
        cell_text = CStr(cell_rng.Value2)

        ' 行数をカウント（行数 = 改行数 + 1）
        If Len(cell_text) > 0 Then
            line_count = UBound(Split(cell_text, vbLf)) + 1
            If line_count > max_line_count Then max_line_count = line_count
        End If

ContinueCell:
    Next cell_rng

    ' 行高を算出して設定
    target_row_height = base_row_height _
                      + (max_line_count - 1) * line_row_height

    target_rng.EntireRow.RowHeight = target_row_height

End Sub