【Excel VBA 再利用コード集】シートのデータを配列に格納する＆取得した配列のサイズを確認（Debug.Print）する

Sub RunGetUsedRangeArray()

    ' Description
    '   使用範囲を配列として取得する


    ' 変数宣言
    Dim wb As Workbook          ' 対象ブック
    Dim ws As Worksheet         ' 対象シート
    Dim used_rng_arr As Variant ' 使用範囲の配列

    ' ブック・シートの取得
    Set wb = ThisWorkbook
    Set ws = wb.Worksheets(1)

    ' 使用範囲を配列として取得
    used_rng_arr = GetUsedRangeArray(ws)
    
    ' 配列サイズをデバッグ出力
    Call DebugPrintArraySize(used_rng_arr, "UsedRange")

End Sub


Function GetUsedRangeArray(ByVal ws As Worksheet) As Variant
    
    ' Description
    ' 指定されたワークシートの使用範囲を判定し、
    ' Cells(1,1) から最終行・最終列までを配列として返す
    '
    ' Arguments
    '   ws  : 対象となるワークシート
    
    
    ' 変数宣言
    Dim last_row As Long
    Dim last_col As Long
    

    ' シートにデータが存在しない場合は Empty を返す
    If ws.Cells.Find("*") Is Nothing Then
        GetUsedRangeArray = Empty
        MsgBox "シートにデータが存在しません。", vbExclamation
        Exit Function
    End If

    ' 最終行・最終列の取得
    With ws
        last_row = .Cells.Find( _
                        "*", _
                        SearchOrder:=xlByRows, _
                        SearchDirection:=xlPrevious _
                    ).Row
        last_col = .Cells.Find( _
                        "*", _
                        SearchOrder:=xlByColumns, _
                        SearchDirection:=xlPrevious _
                    ).Column
    End With

    ' Return：使用範囲を配列として返す
    GetUsedRangeArray = _
        ws.Range( _
            ws.Cells(1, 1), _
            ws.Cells(last_row, last_col) _
        ).Value

End Function


Sub DebugPrintArraySize(ByVal arr As Variant, ByVal label As String)

    ' Description
    ' 配列の行要素数・列要素数をイミディエイトウィンドウに出力する
    '
    ' Arguments
    ' arr   : 行列構造を持つ配列
    ' label : デバッグ出力用の識別子（シート名など）


    ' 配列が Empty の場合処理を中断する
    If IsEmpty(arr) Then
        Debug.Print label & " : 配列が Empty です"
        Exit Sub
    End If

    ' 配列の行要素数・列要素数を出力
    Debug.Print label & _
                " 行要素数=" & (UBound(arr, 1) - LBound(arr, 1) + 1) & _
                " 列要素数=" & (UBound(arr, 2) - LBound(arr, 2) + 1)

End Sub