【簡単エクセル/Excel VBA マクロ】リストから要素をランダムに選択する方法｜フィッシャー・イェーツのシャッフル｜ワンポイントテクニック #007

Option Explicit     ' 変数宣言の強制（タイプミスや意図しないデータ型の使用を防止）


Sub SelectRandomly()


    ' 変数の宣言
    Dim days_array()    As Variant  ' 1週間の曜日を格納する配列
    Dim current_index   As Long     ' 現在の配列インデックス
    Dim random_index    As Long     ' ランダムに選ばれたインデックス
    Dim swapping_day    As String   ' 入れ替え用に記録する一時的な曜日


    ' 配列に1週間分の曜日を設定
    days_array = Array("日", "月", "火", "水", "木", "金", "土")
    
    ' シード値を初期化
    Randomize
    
    ' フィッシャー・イェーツ法でシャッフル：
    ' 配列の最後の要素から順に、ランダムに選んだ別の要素と入れ替えて固定する
    ' UBound=6、LBound=0
    For current_index = UBound(days_array) To LBound(days_array) Step -1
        
        ' LBound～current_indexの範囲（未処理の範囲）でRnd関数を使用して
        ' ランダムなインデックスを生成：
        ' Int関数：小数点以下を切り捨て整数部分を返す　例）Int(5.9)→5、Int(0.999)→0
        ' Rnd関数：0.0 以上 1.0 未満の乱数を返す　例）0.123, 0.999, 0.456 など
        random_index = Int( _
            (current_index - LBound(days_array) + 1) * Rnd _
        ) + LBound(days_array)
        
        ' 現在の要素（current_index）とランダムに選んだ要素（random_index）を交換：
        ' 現在の要素を一時的な変数に保存（上書きを防ぐため）
        swapping_day = days_array(current_index)
        
        ' 現在の位置（インデックス）にランダムに選んだ要素を代入
        days_array(current_index) = days_array(random_index)
        
        ' 一時的に保存していた現在の要素をランダムな位置に代入して交換
        ' ※これをしないと要素が重複する
        days_array(random_index) = swapping_day
    
    Next current_index
    
    ' シャッフル後の最初の3要素を出力
    Debug.Print "ランダムに選ばれた3要素:"
    For current_index = LBound(days_array) To LBound(days_array) + 2
        Debug.Print days_array(current_index)
    Next current_index
    
    
End Sub

ランダムに選ばれた3要素:
日
月
金

ランダムに選ばれた3要素:
水
火
土

ランダムに選ばれた3要素:
水
金
日

Option Explicit     ' 変数宣言の強制（タイプミスや意図しないデータ型の使用を防止）

    ' 変数の宣言
    Dim days_array()    As Variant  ' 1週間の曜日を格納する配列
    Dim current_index   As Long     ' 現在の配列インデックス
    Dim random_index    As Long     ' ランダムに選ばれたインデックス
    Dim swapping_day    As String   ' 入れ替え用に記録する一時的な曜日

    ' 配列に1週間分の曜日を設定
    days_array = Array("日", "月", "火", "水", "木", "金", "土")

    ' シード値を初期化
    Randomize

    ' フィッシャー・イェーツ法でシャッフル：
    ' 配列の最後の要素から順に、ランダムに選んだ別の要素と入れ替えて固定する
    ' UBound=6、LBound=0
    For current_index = UBound(days_array) To LBound(days_array) Step -1
        
        ' LBound～current_indexの範囲（未処理の範囲）でRnd関数を使用して
        ' ランダムなインデックスを生成：
        ' Int関数：小数点以下を切り捨て整数部分を返す　例）Int(5.9)→5、Int(0.999)→0
        ' Rnd関数：0.0 以上 1.0 未満の乱数を返す　例）0.123, 0.999, 0.456 など
        random_index = Int( _
            (current_index - LBound(days_array) + 1) * Rnd _
        ) + LBound(days_array)
        
        ' 現在の要素（current_index）とランダムに選んだ要素（random_index）を交換：
        ' 現在の要素を一時的な変数に保存（上書きを防ぐため）
        swapping_day = days_array(current_index)
        
        ' 現在の位置（インデックス）にランダムに選んだ要素を代入
        days_array(current_index) = days_array(random_index)
        
        ' 一時的に保存していた現在の要素をランダムな位置に代入して交換
        ' ※これをしないと要素が重複する
        days_array(random_index) = swapping_day
    
    Next current_index

      ' シャッフル後の最初の3要素を出力
    Debug.Print "ランダムに選ばれた3要素:"
    For current_index = LBound(days_array) To LBound(days_array) + 2
        Debug.Print days_array(current_index)
    Next current_index